actor TornadoHoldBoss : BaseMM8BDMWep_CBM
{
dropitem "TemgumanDropX"
Weapon.AmmoUse 1
Weapon.AmmoGive 252
Weapon.AmmoUse2 10
Weapon.AmmoGive2 252
Weapon.SlotNumber 4
Obituary "$OB_TENGUSMASH"
Inventory.Pickupmessage "Are you worthy of my challenge?!"
weapon.ammotype "FeelMyPowerAmmo"
weapon.ammotype2 "FeelMyPowerAmmo"
States
{
Spawn:
C_08 A 1
loop
Ready:
THOL I 0 ACS_ExecuteAlways(998,0,860)
THOL I 0 A_GunFlash
THOL L 1 A_WeaponReady
Goto Ready+2
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
THOL L 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
THOL L 1 A_Raise
Loop
Fire:
THOL M 0 A_PlaySoundEx("class/windstart","Weapon")
Hold:
THOL M 0 A_JumpIfInventory("TenguDashStartup",3,"Hold2")
THOL M 1 A_GiveInventory("TenguDashStartup",1)
THOL M 0 A_TakeInventory("UnSolid",1)
THOL M 0 A_ChangeFlag("SOLID",0)
THOL M 0 A_Refire
goto Release
Hold2:
THOL I 0 A_GiveInventory("TenguDashFlag",1)
THOL I 0 A_JumpIf(pitch<350 && pitch>=270, "UpLimit")
//THOL M 0 A_JumpIf(pitch<315 && pitch>=270, "UpLimit")
//THOL M 0 A_JumpIf(pitch>45 && pitch<=90, "DownLimit")
THOL M 1 A_ChangeVelocity(cos(pitch)*24,0,-sin(pitch)*24,CVF_RELATIVE|CVF_REPLACE)
goto RefireCheck
DownLimit:
THOL M 1 A_ChangeVelocity(cos(45)*24,0,-sin(45)*24,CVF_RELATIVE|CVF_REPLACE)
goto RefireCheck
UpLimit:
THOL M 1 A_ChangeVelocity(cos(350)*24,0,-sin(350)*24,CVF_RELATIVE|CVF_REPLACE)
goto RefireCheck
RefireCheck:
THOL M 0 A_TakeInventory("FeelMyPowerAmmo",6)
THOL M 0 A_JumpIfNoAmmo("Release")
THOL M 0 A_Refire
Release:
THOL I 0 A_TakeInventory("TenguDashFlag",1)
THOL I 0 A_TakeInventory("TenguDashStartup",999)
THOL I 0 A_PlaySoundEx("weapon/slashclaw","Weapon")
THOL I 0 A_GiveInventory("TemgumanMain_CI",1)
THOL NO 3
THOL O 6
THOL O 0 A_SpawnItemEx("ReSolidifier")
THOL O 24
THOL VL 3
THOL I 0 A_ClearRefire
Goto Ready+2

AltFire:
THOL I 0 A_JumpIfNoAmmo("NoAmmo")
THOL I 0 A_JumpIf(pitch>80 && pitch<=90 && z-floorz<=0, "AltFireC")
THOL I 0 A_PlaySoundEx("weapon/mbuster","Weapon")
THOL I 0 A_GiveInventory("TemgumanAlt_CI",1)
goto AltEnd
AltFireC:
THOL I 0 A_PlaySoundEx("weapon/DustBit","Weapon")
THOL I 0 A_GiveInventory("TemgumanAlt2_CI",1)
goto AltEnd
AltEnd:
THOL QRQP 3
THOL P 13
THOL STUL 3
THOL I 0 A_Refire
Goto Ready+2

NoAmmo:
THOL I 0
//THOL I 1 ACS_Execute(979,0)
Goto Ready+2

/*Flash:
TNT1 A 0 A_JumpIfInventory("FeelMyPowerAmmo",1,"Flash1")
TNT1 A 0 A_JumpIf(z-floorz>0,"StartOver")
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
TNT1 A 0 A_GiveInventory("FeelMyPowerAmmo",4)
Flash1:
TNT1 A 0 A_JumpIfInventory("TenguDashFlag",1,"StartOver")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,3)
TNT1 A 0 A_JumpIf(momz>=0,2)
TNT1 A 0 A_JumpIfInventory("TenguFlagH",1,"Hover")
TNT1 A 0 A_JumpIf(z-floorz>0,"StartOver")
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
TNT1 A 0 A_GiveInventory("FeelMyPowerAmmo",4)
loop
Hover:
TNT1 A 0 ThrustThingZ(0,3,1,0)
TNT1 A 0 A_TakeInventory("FeelMyPowerAmmo",1)
TNT1 A 1 ACS_ExecuteAlways(191,0,4)
goto Flash
NoFlash:
TNT1 A 0
stop
StartOver:
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
goto Flash*/

Flash:
TNT1 A 0 A_JumpIfInventory("TornadoThrusted",1,"FlashB")
TNT1 A 0 A_JumpIfInventory("TenguDashFlag",1,"FlashDashing")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,"Flash1FD")
TNT1 A 0 A_JumpIfInventory("FeelMyPowerAmmo",1,2)
TNT1 A 0 A_Jump(256,2)
TNT1 A 0 A_JumpIfInventory("TenguFlagH",1,"HoverCheck1")
TNT1 A 0
Flash1:
//TNT1 A 0 A_GiveInventory("EnvironmentGravity",1)
Flash1FD:
TNT1 A 0 A_JumpIfInventory("IsDead",1,"NoFlash")
TNT1 A 0 A_GiveInventory("FeelMyPowerAmmo",2)
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
goto Flash
HoverCheck1:
TNT1 A 0 A_JumpIf(momz<0,"Hover")
goto Flash1

FlashDashing:
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
goto FlashB
Hover:
TNT1 A 0 A_JumpIfInventory("IsDead",1,"NoFlash")
TNT1 A 0 A_TakeInventory("FeelMyPowerAmmo",1)
//TNT1 A 0 A_SetGravity(0.000001)
//TNT1 A 0 ThrustThingZ(0,3,1,0)
TNT1 A 0 ThrustThingZ(0,2,1,0)
TNT1 A 1 ACS_ExecuteAlways(191,0,4)
goto FlashB


FlashB:
TNT1 A 0 A_JumpIf(z-floorz<=0,"FoundGround")
TNT1 A 0 A_JumpIfInventory("TenguDashFlag",1,"FlashDashing")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,"Flash2FD")
TNT1 A 0 A_JumpIfInventory("FeelMyPowerAmmo",1,2)
TNT1 A 0 A_Jump(256,2)
TNT1 A 0 A_JumpIfInventory("TenguFlagH",1,"HoverCheck2")
TNT1 A 0
Flash2:
//TNT1 A 0 A_GiveInventory("EnvironmentGravity",1)
Flash2FD:
TNT1 A 1 ACS_ExecuteAlways(191,0,0)
goto FlashB
HoverCheck2:
TNT1 A 0 A_JumpIf(momz<0,"Hover")
goto Flash2
FoundGround:
TNT1 A 0 A_TakeInventory("TornadoThrusted",1)
goto Flash+1

NoFlash:
TNT1 A 0
stop
}
}


actor TornadoHoldPodB : TornadoHoldPod
{
damage(15) 
Translation "192:192=4:4","199:199=112:112"
ReactionTime 1
states
{
Spawn:
TORH O 0
TORH O 0 A_Recoil(-1)
TORH O 1 A_CheckFloor("SpawnD")
goto Spawn+2
SpawnD:
TORH O 1 A_CountDown
wait
Death:
TNT1 A 0 A_Stop
TNT1 A 1 A_SpawnItemEx("TornadoHoldB",0,0,0,0,0,0,0,1)
stop
XDeath:
TORH O 0 A_Stop
TORH O 0 ThrustThingZ(0,120,1,0)
TORH OOOOOOOOOO 1 A_CheckFloor("Death")
goto Death
}
}

actor TornadoHoldPodBB : TornadoHoldPodB{translation "192:192=205:205", "199:199=74:74"}
actor TornadoHoldPodBR : TornadoHoldPodB{translation "192:192=171:171", "199:199=41:41"}
actor TornadoHoldPodBO : TornadoHoldPodB{translation "192:192=104:104", "199:194=128:128"}
actor TornadoHoldPodBP : TornadoHoldPodB{translation "192:192=229:229", "199:199=232:232"}

actor TornadoHoldPodC : TornadoHoldPodB
{
states
{
Death:
TORH O 0 A_Stop
TORH O 0 A_SpawnItemEx("TornadoHoldC",0,0,0,0,0,0,0,1)
stop
}
}

actor TornadoHoldPodCB : TornadoHoldPodC{translation "192:192=205:205", "199:199=74:74"}
actor TornadoHoldPodCR : TornadoHoldPodC{translation "192:192=171:171", "199:199=41:41"}
actor TornadoHoldPodCO : TornadoHoldPodC{translation "192:192=104:104", "199:194=128:128"}
actor TornadoHoldPodCP : TornadoHoldPodC{translation "192:192=229:229", "199:199=232:232"}


actor TornadoHoldB : TornadoHold
{
WallBounceFactor 1.0
BounceCount 10
ReactionTime 15
states
{
Spawn:
TORH O 1 A_CheckFloor("Change")
TORH O 0 A_CountDown
Loop
Change:
//TORH B 0 A_Recoil(-5)
TORH OP 1
goto Floor
Floor:
TORH Q 0 A_ChangeFlag("MISSILE",1)
TORH Q 0 A_ChangeFlag("FLOORHUGGER",1)
TORH Q 0 A_ChangeFlag("DOOMBOUNCE",1)
//TORH Q 0 A_ChangeFlag("NOCLIP",1)
TORH Q 0 A_Recoil(-5)
TORH Q 0 A_PlaySoundEx("weapon/tornadohold","Weapon")
TORH Q 0
TORH Q 0 A_SpawnItemEx("HoldingTornadoB",0,0,15,0,0,0,0,33)
TORH QRQR 2 ThrustThing(angle*256/360,0)
TORH Q 0 A_CountDown
goto Floor+5
}
}

actor TornadoHoldC : TornadoHoldB
{
states
{
Change:
//TORH B 0 A_Recoil(-5)
TORH OP 1
goto Floor
Floor:
TORH Q 0 A_ChangeFlag("MISSILE",1)
TORH Q 0 A_ChangeFlag("FLOORHUGGER",1)
TORH Q 0 A_ChangeFlag("DOOMBOUNCE",1)
//TORH Q 0 A_ChangeFlag("NOCLIP",1)
TORH Q 0 //A_Recoil(-5)
TORH Q 0 A_PlaySoundEx("weapon/tornadohold","Weapon")
TORH Q 0
TORH Q 0 A_SpawnItemEx("HoldingTornadoB",0,0,15,0,0,0,0,33)
TORH QRQR 2 ThrustThing(angle*256/360,0)
TORH Q 0 A_CountDown
goto Floor+5
}
}

actor HoldingTornadoB : HoldingTornado
{
damage(12)
damagetype "TornadoHoldB"
states
{
Spawn:
TORH SS 0 ThrustThingZ(0,20,0,0)
Loop1:
TORH S 0 A_JumpIf(z-floorz>=288,"Death")
TORH SSS 1 A_JumpIfCloser(40,"Lift1")
Loop2:
TORH T 0 A_JumpIf(z-floorz>=288,"Death")
TORH TTT 1 A_JumpIfCloser(40,"Lift2")
Loop3:
TORH U 0 A_JumpIf(z-floorz>=288,"Death")
TORH UUU 1 A_JumpIfCloser(40,"Lift3")
goto Loop1
Lift1:
TORH S 1 A_GiveToTarget("TornadoThrusterB",1)
TORH SS 1
goto Loop2
Lift2:
TORH T 1 A_GiveToTarget("TornadoThrusterB",1)
TORH TT 1
goto Loop3
Lift3:
TORH U 1 A_GiveToTarget("TornadoThrusterB",1)
TORH UU 1
goto Loop1
Death:
TORH T 1 A_SpawnItemEx("TornadoHoldEndB",0,0,0,0,0,0,0,1)
stop
XDeath:
TORH U 0 
TORH U 0 A_SpawnItemEx("TornadoLifterB",0,0,0,0,0,momz,0,1)
stop
}
}

actor TornadoLifterB : HoldingTornadoB
{
+RIPPER
DAMAGE (0)
States
{
Death:
TORH U 0 
stop
XDeath:
TORH U 0 
stop
}
}

actor TornadoHoldEndB
{
+NOINTERACTION
Scale 2.5
States
{
Spawn:
TORH UTSUTS  3
stop
}
}

actor TornadoThrusterB : TornadoThruster
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,3)
TNT1 A 0 A_GiveInventory("TornadoThrusted",1)
TNT1 A 0 ThrustThingZ(0,20,0,0)
TNT1 A 0
stop
}
}

actor FeelMyPowerAmmo : Ammo
{
+INVENTORY.IGNORESKILL 
inventory.amount 1
inventory.maxamount 252
}

actor TenguFlagH : OnceC {}

actor TenguDashFlag : OnceC {}

actor TenguDashStartup : Inventory
{
inventory.amount 1
inventory.maxamount 3
}

actor TornadoThrusted : OnceC {}

actor TenguHoverItem : CustomInventory
{
inventory.amount 1
inventory.maxamount 1
inventory.icon "TenIcon"
scale 2.0
inventory.pickupmessage "That ain't Falco."
+INVBAR
states
{
Spawn:
TENI X 1
loop
Use:
TNT1 A 0 A_PlaySoundEx("item/ItemUseMM9","SoundSlot6")
TNT1 A 0 A_JumpIfInventory("TenguFlagH",1,"Take")
TNT1 A 0 A_GiveInventory("TenguFlagH",1)
fail
Take:
TNT1 A 0 A_TakeInventory("TenguFlagH",999)
fail
}
}

actor TenguSmash
{
PROJECTILE
Radius 2
Height 2
scale 2.5
damage (0)
+DONTBLAST
+RIPPER
+NOEXPLODEFLOOR
Obituary "$OB_TENGUSMASH"
damagetype "GravityT1"
speed 40
Translation "192:192=4:4","199:199=112:112"
states
{
Spawn:
TORH L 0
TORH L 1
TORH M 1 A_Explode(5,80,0,0,80)
TORH M 0 A_SpawnItemEx("TenguSmash2",0,0,0,momx,momy,momz,0,9)
stop
}
}

actor TenguSmashB : TenguSmash{translation "192:192=205:205", "199:199=74:74"}
actor TenguSmashR : TenguSmash{translation "192:192=171:171", "199:199=41:41"}
actor TenguSmashO : TenguSmash{translation "192:192=104:104", "199:199=128:128"}
actor TenguSmashP : TenguSmash{translation "192:192=229:229", "199:199=232:232"}

actor TenguSmash2 : TenguSmash
{

damagetype "GravityB2"
states
{
Spawn:
TORH N 0
TORH NL 1 //A_Explode(10,80,0,0,8)
TORH L 0 A_SpawnItemEx("Kamaitachi",0,0,0,momx,momy,momz,0,9)
TORH L 0 
stop
}
}

actor GravityCollideT : BasicExplosion
{
Obituary "$OB_TENGUSMASH"
damagetype "GravityB2"
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_Explode(3,15,0,0,15)
TNT1 A 1
stop
}
}

actor GravityCollideTX : BasicExplosion
{
Obituary "$OB_TENGUSMASHX"
damagetype "GravityB2"
states
{
Spawn:
TNT1 A 0
TNT1 A 0 A_Explode(3,15,0,0,15)
TNT1 A 1
stop
}
}

actor Kamaitachi
{
PROJECTILE
+RIPPER
Radius 7
Height 7
scale 2.5
damage (8)
//damagetype "TornadoHoldB"
Obituary "$OB_KAMAITACHI"
damagetype "Kamaitachi"

+HEXENBOUNCE
+CANBOUNCEWATER
WallBounceFactor 0.95
BounceCount 3
states
{
Spawn:
TORH I 0
TORH I 0 A_JumpIf( momx*momx + momy*momy < 324 && momz == 0, "Death")
TORH I 0 A_PlaySoundEx("weapon/tengushot","Weapon")
Spawn2:
TORH I 0 A_Explode(12,56,0,0,8)
TORH III 1 ThrustThingZ(0,4,0,1)
TORH I 0 A_Explode(12,56,0,0,8)
TORH JJJ 1 ThrustThingZ(0,4,0,1)
TORH I 0 A_Explode(12,56,0,0,8)
TORH KKK 1 ThrustThingZ(0,4,0,1)
goto Spawn2
Death:
TNT1 A 0
stop
}
}

actor TornadoHeld
{
Height 0
Radius 0
+NOINTERACTION
-SOLID
+NOGRAVITY
+MISSILE
reactiontime 4
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3",1)

TNT1 A 0 A_GiveInventory("CutterFlag",1)
TNT1 A 0 A_JumpIfInventory("CutterFlag",4,"Spawn2")
goto Spawn+1

Spawn2:
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRiseB",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRiseB",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRiseB",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2B",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2B",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise2B",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3B",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3B",1)
TNT1 A 0 A_JumpIfInTargetInventory("TornadoHeldEnd",1,"Death")
TNT1 A 1 A_GiveToTarget("TornadoHeldRise3B",1)

TNT1 A 0 A_Countdown
loop
Death:
TNT1 A 0
stop
}
}

actor TornadoHeldRise : CustomInventory
{
inventory.amount 1
inventory.maxamount 1
States
{
Spawn:
TNT1 A 0
stop
Pickup:
TNT1 A 0 A_JumpIfInventory("CutterFlag",998,"Cancel")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,"Cancel")
TNT1 A 0 A_JumpIf(!(health>0),"Cancel")
TNT1 A 0 A_SpawnItemEx("TornadoHeldFX", 0, 0, 0, momx, momy, momz, 0, SXF_ABSOLUTEMOMENTUM, 0)
Pickup2:
TNT1 A 0 A_GiveInventory("TornadoHeldSlow",1)
//TNT1 A 0 A_ChangeVelocity(momx,momy,3,CVF_REPLACE)
TNT1 A 0 ThrustThingZ(0,20,0,0)
//TNT1 A 0 A_Print("Rose")
stop
Cancel:
TNT1 A 0 A_GiveInventory("TornadoHeldEnd",1)
stop
}
}

actor TornadoHeldRise2 : TornadoHeldRise
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("CutterFlag",998,"Cancel")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,"Cancel")
TNT1 A 0 A_JumpIf(!(health>0),"Cancel")
TNT1 A 0 A_SpawnItemEx("TornadoHeldFX2", 0, 0, 0, momx, momy, momz, 0, SXF_ABSOLUTEMOMENTUM, 0)
goto Pickup2
}
}

actor TornadoHeldRise3 : TornadoHeldRise
{
States
{
Pickup:
TNT1 A 0 A_JumpIfInventory("CutterFlag",998,"Cancel")
TNT1 A 0 A_JumpIfInventory("FlightDisableFlag",1,"Cancel")
TNT1 A 0 A_JumpIf(!(health>0),"Cancel")
TNT1 A 0 A_SpawnItemEx("TornadoHeldFX3", 0, 0, 0, momx, momy, momz, 0, SXF_ABSOLUTEMOMENTUM, 0)
goto Pickup2
}
}

actor TornadoHeldRiseB : TornadoHeldRise
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz>=320,"Cancel")
goto "Super::Pickup"
}
}

actor TornadoHeldRise2B : TornadoHeldRise2
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz>=320,"Cancel")
goto "Super::Pickup"
}
}

actor TornadoHeldRise3B : TornadoHeldRise3
{
States
{
Pickup:
TNT1 A 0 A_JumpIf(z-floorz>=320,"Cancel")
goto "Super::Pickup"
}
}

actor TornadoHeldFX
{
scale 2.5
-SOLID
+NOGRAVITY
+CLIENTSIDEONLY

+DONTBLAST
+NOINTERACTION

Translation "192:192=4:4","199:199=112:112"
States
{
Spawn:
TORH S 0
TORH S 1
stop
}
}

actor TornadoHeldFX2 : TornadoHeldFX
{
States
{
Spawn:
TORH T 0
TORH T 1
stop
}
}

actor TornadoHeldFX3 : TornadoHeldFX
{
States
{
Spawn:
TORH U 0
TORH U 1
stop
}
}


actor TornadoHeldEnd : PowerDamage
{
powerup.duration 3
damagefactor "normal", 1.0
}

actor TornadoHeldSlow : PowerSpeed
{
Speed 0.75
powerup.duration 3
}

actor TemgumanDropX : BasicHelper
{
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_Jump(256,1,2)
TNT1 A 1 A_SpawnItemEx("TornadoHoldWepCDropped")
stop
TNT1 A 1 A_SpawnItemEx("TenguBladeWepCDropped")
stop
}
}

actor TemgumanMain_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TenguSmash",0,0,-8,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TenguSmashB",0,0,-8,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TenguSmashR",0,0,-8,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TenguSmashO",0,0,-8,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TenguSmashP",0,0,-8,0)
goto Done
}
}

actor TemgumanAlt_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodB",0,1,-8,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodBB",0,1,-8,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodBR",0,1,-8,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodBO",0,1,-8,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodBP",0,1,-8,0)
goto Done
}
}

actor TemgumanAlt2_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodC",0,1,-8,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodCB",0,1,-8,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodCR",0,1,-8,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodCO",0,1,-8,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("TornadoHoldPodCP",0,1,-8,0)
goto Done
}
}
