actor ScorchWheelBoss : BaseMM8BDMWep_CBM
{
dropitem "ScorchWheelWepCDropped"
Weapon.AmmoUse 8
Weapon.AmmoGive 0
Weapon.SlotNumber 1
Obituary "$OB_SCORCHWHEEL"
weapon.ammotype "Petrol"
States
{
Spawn:
C_07 H 1
loop
Ready:
TUCA A 0 ACS_ExecuteAlways(998,0,847)
TUCA A 0 A_JumpIfInventory("Petrol",1,"Ready2")
TUCA A 0 ACS_ExecuteAlways(191,0,0)
TUCA A 7 A_WeaponReady(12)
TUCA A 0 A_GiveInventory("Petrol",2)
Goto Ready+1
Ready2:
TUCA A 0 A_JumpIfInventory("Petrol",8,"Ready3")
TUCA A 0 ACS_ExecuteAlways(191,0,0)
TUCA A 7 A_WeaponReady(4)
TUCA A 0 A_GiveInventory("Petrol",2)
loop
Ready3:
TUCA A 0 ACS_ExecuteAlways(191,0,0)
TUCA A 7 A_WeaponReady
TUCA A 0 A_GiveInventory("Petrol",2)
loop
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
TUCA A 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
TUCA A 1 A_Raise
Loop
Fire:
TUCA A 0 A_JumpIfInventory("TurboCar",1,"HONKHONK")
TUCA A 0 A_JumpIfInventory("CarCount",6,"StopCar")
TUCA A 0 A_TakeInventory("TurboCar",99)
TUCA A 0 A_JumpIfNoAmmo("NoAmmo")
TUCA A 0 A_TakeInventory("BasicArmor",9999)
TUCA BCDEF 2
TUCA A 0 A_PlaySoundEx("weapon/WheelGoGoGo","Weapon")
Goto Hold
Hold:
TNT1 A 0 ACS_ExecuteAlways(191,0,1)
TNT1 A 0 A_JumpIfInventory("WheelCount",15,"Throw")
TNT1 A 0 A_GiveInventory("WheelFrameCheck",1)
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",6,"Frame6")
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",5,"Frame5")
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",4,"Frame4")
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",3,"Frame3")
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",2,"Frame2")
TNT1 A 0 A_JumpIfInventory("WheelFrameCheck",1,"Frame1")
goto Throw
Frame1:
TNT1 A 0 A_GiveInventory("WheelCount",1)
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX1",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw
Frame2:
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX2",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw
Frame3:
TNT1 A 0 A_GiveInventory("WheelCount",1)
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX3",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw
Frame4:
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX4",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw
Frame5:
TNT1 A 0 A_GiveInventory("WheelCount",1)
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX5",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw
Frame6:
TNT1 A 0 A_TakeInventory("WheelFrameCheck",999)
TNT1 AAA 1 A_SpawnItemEx("ScorchWheelBFX6",0,0,0,momx,momy,momz,0,9,0)
TNT1 A 0 A_Refire
Goto Throw

Throw:
TNT1 A 0 ACS_ExecuteAlways(191,0,0)
TNT1 A 0 A_TakeInventory("WheelCount",99)
TNT1 A 0 A_GiveInventory("TurbomanMain_CI",1)
TUCA GH 2 A_ClearRefire
Goto Ready+1

Altfire:
TUCA C 0 A_JumpIfInventory("CarCount",6,"StopCar")
TUCA C 0 A_JumpIf(z-floorz==0,"SlideSlide")//A_JumpIf(momz==0, "SlideSlide")
TNT1 A 0 SetPlayerProperty(0,0,0)
Goto Ready+1
SlideSlide:
TNT1 A 0 A_JumpIfInventory("Petrol",1,"Continue")
goto Ready+1
Continue:
TNT1 A 0 SetPlayerProperty(0,1,0)
TNT1 A 0 A_GiveInventory("SelfTotallyFrozen",1) 
TNT1 A 0 A_JumpIfNoAmmo("NoAmmo")
TNT1 A 0 A_GiveInventory("TurboCar",1)
TUCA XY 2 A_PlaySoundEx("classes/CarCharge","Weapon")
TNT1 A 0 A_GiveInventory("CarCount",1)
TNT1 A 0 A_JumpIfInventory("CarCount",6,"Go")
Goto Continue
Go:
TNT1 A 0 A_GiveInventory("SelfTotallyUnfrozen",1)
TNT1 A 0 A_PlaySoundEx("classes/CarGoGo","Weapon")
CarMode:
TNT1 A 0 A_GiveInventory("TurboCar",1)
//TNT1 A 0 A_Recoil(-7)
//TNT1 A 0 A_ChangeVelocity(14,0,momz,3)
TNT1 A 0 A_ChangeVelocity(28,0,momz,3)
TNT1 A 0 A_SpawnItemEx("CarRadius",0,0,16)
TNT1 A 0 A_TakeInventory("Petrol",1)
TUCA X 1 A_WeaponReady(6)
TUCA Y 1 A_WeaponReady(2)
TNT1 A 0 A_JumpIfInventory("Petrol",1,"CarMode")
goto StopCar

HONKHONK:
TNT1 A 0 A_PlaySound("classes/CarHonk",6,0.5)
goto CarModeX
CarModeX:
TNT1 A 0 A_GiveInventory("TurboCar",1)
TNT1 A 0 A_ChangeVelocity(28,0,momz,3)
TNT1 A 0 A_SpawnItemEx("CarRadius",0,0,16)
TNT1 A 0 A_TakeInventory("Petrol",1)
TUCA YX 1 A_WeaponReady(6)
TNT1 A 0 A_JumpIfInventory("Petrol",1,"CarModeX")
goto StopCar

StopCar:
TNT1 A 0 A_TakeInventory("TurboCar",999)
TNT1 A 0 A_TakeInventory("CarCount",999)
TNT1 A 0 A_GiveInventory("NoCar",1)
TNT1 A 0 SetPlayerProperty(0,0,0)
TUCA G 33
TUCA H 2
TUCA H 0 A_TakeInventory("NoCar",1)
Goto Ready+1
NoAmmo:
TUCA A 0
//TUCA A 1 ACS_Execute(979,0)
Goto Ready+1
}
}

actor ScorchWheelB : ScorchWheel
{
Translation "202:202=210:210", "199:199=42:42"
damagetype "ScorchWheelB"
speed 20//16
States
{
Spawn:
TUCA KLMNOP 2 A_Explode(10,96,0)
loop
Death:
//TNT1 A 0 A_CustomMissile("ScorchWheelB2",0,0,0,2,0)
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2",0,0,0,16,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}

actor ScorchWheelBB : ScorchWheelB{translation "202:202=205:205", "199:199=74:74"}
actor ScorchWheelBR : ScorchWheelB{translation "202:202=171:171", "199:199=41:41"}
actor ScorchWheelBO : ScorchWheelB{translation "202:202=104:104", "199:199=128:128"}
actor ScorchWheelBP : ScorchWheelB{translation "202:202=229:229", "199:199=232:232"}


actor ScorchWheelB2 : ScorchWheel
{
ReactionTime 100
damagetype "ScorchWheelB"
States
{
Spawn:
TUCA KL 2 A_Explode(11,96,0)
TUCA L 0 A_GiveInventory("Clip",1)
TUCA MNOPKL 2 A_Explode(11,96,0)
TUCA M 0 A_CountDown
goto Spawn+3
Death:
TNT1 A 0 A_JumpIfInventory("Clip",1,"Continue")
TNT1 AAAA 0 A_SpawnItemEx("ScorchBitB",0,0,0,random(-10,10),random(-10,10),random(10,15),random(0,360),1)
stop
Continue:
TNT1 A 0 A_SpawnItemEx("ScorchWheelB2",0,0,0,16,0,0,0,1)
TNT1 A 1 A_SpawnItemEx("OilPitIgnite",0,0,8)
stop
}
}

actor ScorchBitB : ScorchBit
{
States
{
Spawn:
TUCA Q 2
TNT1 A 2
TUCA Q 2
TNT1 A 2
TUCA Q 2
TNT1 A 2
TUCA Q 2
TNT1 A 2
TUCA Q 2
TNT1 A 2
stop
}
}

actor ScorchWheelBFX1
{
scale 2.5
- SOLID
+NOGRAVITY
+NOINTERACTION
+CLIENTSIDEONLY
+NOTIMEFREEZE
States
{
Spawn:
TUCA K 0
TUCA K 1
stop
}
}

actor ScorchWheelBFX2 : ScorchWheelBFX1{States{Spawn:TUCA L 0
TUCA L 1
stop}}

actor ScorchWheelBFX3 : ScorchWheelBFX1{States{Spawn:TUCA M 0
TUCA M 1
stop}}

actor ScorchWheelBFX4 : ScorchWheelBFX1{States{Spawn:TUCA N 0
TUCA N 1
stop}}

actor ScorchWheelBFX5 : ScorchWheelBFX1{States{Spawn:TUCA O 0
TUCA O 1
stop}}

actor ScorchWheelBFX6 : ScorchWheelBFX1{States{Spawn:TUCA P 0
TUCA P 1
stop}}

actor CarRadius : BasicExplosion
{
Obituary "$OB_TURBORAM"
Damagetype "ClassPainLess2"
//Damagetype "ScorchWheel"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(8,160,0)
stop
}
}

actor Petrol : Ammo
{
inventory.amount 1
inventory.maxamount 24
+INVENTORY.IGNORESKILL
}

actor TurboCar : OnceC {}

actor NoCar : OnceC {}

actor CarCount : Inventory
{
inventory.amount 1
inventory.maxamount 6
}


actor TurbomanMain_CI : TeamColor_CI
{
states
{
FireX:
TNT1 A 0 A_FireCustomMissile("ScorchWheelB",0,1,0,0)
goto Done
FireB:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBB",0,1,0,0)
goto Done
FireR:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBR",0,1,0,0)
goto Done
FireO:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBO",0,1,0,0)
goto Done
FireP:
TNT1 A 0 A_FireCustomMissile("ScorchWheelBP",0,1,0,0)
goto Done
}
}
